'##############
'Rollband Script
'##############

'Rollbandanimation für ein SD79-Rollband (Ziffern manuell, Ziel automatisch)

'(c) 20.02.2009 Rüdiger Hülsmann
'(c) 17.09.2013 Marcel Kuhnt

'Script Version: 1.5
'Omsi release: 1.0

'Needs:
'- none


'Revision History:
'- Marcel Kuhnt 10.08.2009 Added Revision History
'- Marcel Kuhnt 13.04.2010 Added Line List Script
'- Rüdiger Hülsmann 11.10.2010 New AI Scheduled trigger
'- Rüdiger Hülsmann 17.10.2010 line offset added
'- Marcel Kuhnt 25.01.2011 Reduced error offset
'- Marcel Kuhnt 03.02.2011 /^\ corrected
'- Marcel Kuhnt 30.10.2012 Neue Busbar-Logik
'- Marcel Kuhnt 04.12.2012 Steckschilder für ausgewählte Ziele
'- Marcel Kuhnt 18.12.2012 Seitenschild
'- Marcel Kuhnt 17.09.2013 Einführung von Unterordnern über Hofdatei-Globalstring 1
'- Marcel Kuhnt 13.10.2013 Neuer Seitenschildpfad

'------------------------------------------------------------------------------------------

{trigger:rollband_auf}
1 (S.L.rlbnd_auf_pressed)
(T.L.rlbnd_taste_ein)
{end}

{trigger:rollband_auf_off}
0 (S.L.rlbnd_auf_pressed)
(T.L.rlbnd_taste_aus)
{end}

{trigger:rollband_ab}
1 (S.L.rlbnd_ab_pressed)
(T.L.rlbnd_taste_ein)
{end}

{trigger:rollband_ab_off}
0 (S.L.rlbnd_ab_pressed)
(T.L.rlbnd_taste_aus)
{end}


{trigger:rollband_sync}
1 (S.L.rlbnd_sync_pressed)
(T.L.rlbnd_taste_ein)
(L.L.elec_busbar_main) (C.L.elec_busbar_minV) >
{if}
(S.L.rlbnd_running_dn)
0 (S.L.rlbnd_ziel_target)
{endif}
{end}

{trigger:rollband_sync_off}
0 (S.L.rlbnd_sync_pressed)
(T.L.rlbnd_taste_aus)
{end}




'*******************************************
' Trigger für Tastaturbedienung

{trigger:bus_rollband_up_step}
(L.L.rlbnd_activekurbel) 4 =
{if}
1 (S.L.rlbnd_auf_pressed)
(T.L.rlbnd_taste_ein)
{endif}
{end}

{trigger:bus_rollband_up_step_off}
(L.L.rlbnd_activekurbel) 4 =
{if}
0 (S.L.rlbnd_auf_pressed)
(T.L.rlbnd_taste_aus)
{endif}
{end}

{trigger:bus_rollband_dn_step}
(L.L.rlbnd_activekurbel) 4 =
{if}
1 (S.L.rlbnd_ab_pressed)
(T.L.rlbnd_taste_ein)
{endif}
{end}

{trigger:bus_rollband_dn_step_off}
(L.L.rlbnd_activekurbel) 4 =
{if}
0 (S.L.rlbnd_ab_pressed)
(T.L.rlbnd_taste_aus)
{endif}
{end}

{trigger:bus_rollband_up}
(L.L.rlbnd_activekurbel) 1 =
{if}
(L.L.rlbnd_ln1) (L.S.timegap) 1 / + 0 max 15 min (S.L.rlbnd_ln1)
(M.L.rollband_actu)
(M.L.rollband_refresh_setLineTo)
{else}
(L.L.rlbnd_activekurbel) 2 =
{if}
(L.L.rlbnd_ln2) (L.S.timegap) 1 / + 0 max 15 min (S.L.rlbnd_ln2)
(M.L.rollband_actu)
(M.L.rollband_refresh_setLineTo)
{else}
(L.L.rlbnd_activekurbel) 3 =
{if}
(L.L.rlbnd_ln3) (L.S.timegap) 1 / + 0 max 15 min (S.L.rlbnd_ln3)
(M.L.rollband_actu)
(M.L.rollband_refresh_setLineTo)
{endif}
{endif}
{endif}
{end}

{trigger:bus_rollband_dn}
(L.L.rlbnd_activekurbel) 1 =
{if}
(L.L.rlbnd_ln1) (L.S.timegap) 1 / - 0 max 15 min (S.L.rlbnd_ln1)
(M.L.rollband_actu)
(M.L.rollband_refresh_setLineTo)
{else}
(L.L.rlbnd_activekurbel) 2 =
{if}
(L.L.rlbnd_ln2) (L.S.timegap) 1 / - 0 max 15 min (S.L.rlbnd_ln2)
(M.L.rollband_actu)
(M.L.rollband_refresh_setLineTo)
{else}
(L.L.rlbnd_activekurbel) 3 =
{if}
(L.L.rlbnd_ln3) (L.S.timegap) 1 / - 0 max 15 min (S.L.rlbnd_ln3)
(M.L.rollband_actu)
(M.L.rollband_refresh_setLineTo)
{endif}
{endif}
{endif}
{end}


{trigger:bus_rollband_setL1}
1 (S.L.rlbnd_activekurbel)
{end}

{trigger:bus_rollband_setL2}
2 (S.L.rlbnd_activekurbel)
{end}

{trigger:bus_rollband_setL3}
3 (S.L.rlbnd_activekurbel)
{end}

{trigger:bus_rollband_setT}
4 (S.L.rlbnd_activekurbel)
{end}


'****************************************************************
'** MCQ 24.5.2009 - Trigger für AI-Scheduled-Initialisierung: **
'****************************************************************

{trigger:ai_scheduled_settarget}

'Hier wird das automatische Rollband eingestellt:
1 (S.L.elec_busbar_main_sw)
1.0 (S.L.elec_V_battery)
(L.L.AI_target_index) s0 (M.V.GetTerminusCode) s1
'Wenn der Terminus-Code größer als 1000 ist, dann bitte Steckschild verwenden:
1000 >
{if}
l1 1000 - (S.L.rlbnd_steckschild_index)
l0 (S.L.rlbnd_steckschild_Termindex)
'Rollband auf 0:
0 (S.L.rlbnd_ziel_target)
{else}
l0 (S.L.rlbnd_ziel_target)
-1 (S.L.rlbnd_steckschild_Termindex)

'Wenn der Bitmap-String in Verwendung ist, dann den als Integer interpretieren und Steckschild zusätzlich setzen:
l0 6 (M.V.GetTerminusString) $StrToFloat s1
l1 1000 >
{if}
l1 1000 - (S.L.rlbnd_steckschild_index)
l0 (S.L.rlbnd_steckschild_Termindex)
{endif}

{endif}
(M.L.rollband_setsteckschild)


' Und gleich "schnell" gekurbelt: (aber +0.1, damit das Zielband noch aktualisiert wird)
(L.L.rlbnd_ziel_target) 0.1 + (S.L.rlbnd_ziel)

'Hier werden die Nummernrollbänder eingestellt:

'Nummern-String holen:


'Vorgehensweise pro Ziffer: zunächst wird die Ziffer "ausgeschnitten", dann jeweils dubliziert, damit
'jeweils ein Exemplar der ausgeschnittenen Ziffer im Cache bleibt (die andere geht beim $= verloren)

'1. Ziffer:

(L.$.SetLineTo) 1 $SetLengthL $d

" " $= {if} 0 s1 {endif} $d
"N" $= {if} 2 s1 {endif} $d
"g" $= {if} 3 s1 {endif} $d
"0" $= {if} 4 s1 {endif} $d
"1" $= {if} 5 s1 {endif} $d
"2" $= {if} 6 s1 {endif} $d
"3" $= {if} 7 s1 {endif} $d
"4" $= {if} 8 s1 {endif} $d
"5" $= {if} 9 s1 {endif} $d
"6" $= {if} 10 s1 {endif} $d
"7" $= {if} 11 s1 {endif} $d
"8" $= {if} 12 s1 {endif} $d
"9" $= {if} 13 s1 {endif} $d
"/" $= {if} 14 s1 {endif} $d
"A" $= {if} 16 s1 {endif} $d
"E" $= {if} 17 s1 {endif}

'2. Ziffer:

(L.$.SetLineTo) 2 $SetLengthL 1 $SetLengthR $d

" " $= {if} 0 s2 {endif} $d
"E" $= {if} 1 s2 {endif} $d
"A" $= {if} 2 s2 {endif} $d
"h" $= {if} 3 s2 {endif} $d
"0" $= {if} 4 s2 {endif} $d
"1" $= {if} 5 s2 {endif} $d
"2" $= {if} 6 s2 {endif} $d
"3" $= {if} 7 s2 {endif} $d
"4" $= {if} 8 s2 {endif} $d
"5" $= {if} 9 s2 {endif} $d
"6" $= {if} 10 s2 {endif} $d
"7" $= {if} 11 s2 {endif} $d
"8" $= {if} 12 s2 {endif} $d
"9" $= {if} 13 s2 {endif} $d
"^" $= {if} 14 s2 {endif}

'3. Ziffer:

(L.$.SetLineTo) 3 $SetLengthL 1 $SetLengthR $d

" " $= {if} 0 s3 {endif} $d
"E" $= {if} 1 s3 {endif} $d
"N" $= {if} 2 s3 {endif} $d
"A" $= {if} 3 s3 {endif} $d
"0" $= {if} 4 s3 {endif} $d
"1" $= {if} 5 s3 {endif} $d
"2" $= {if} 6 s3 {endif} $d
"3" $= {if} 7 s3 {endif} $d
"4" $= {if} 8 s3 {endif} $d
"5" $= {if} 9 s3 {endif} $d
"6" $= {if} 10 s3 {endif} $d
"7" $= {if} 11 s3 {endif} $d
"8" $= {if} 12 s3 {endif} $d
"9" $= {if} 13 s3 {endif} $d
"\" $= {if} 14 s3 {endif}



' Das ultimative Sahnehäubchen: die drei Rollbänder werden noch zufällig verrutscht...! *ggg*

10 random 5 - 100 / l1 + (S.L.rlbnd_ln1_target)
10 random 5 - 100 / l2 + (S.L.rlbnd_ln2_target)
10 random 5 - 100 / l3 + (S.L.rlbnd_ln3_target)

(L.L.rlbnd_ln1_target) (S.L.rlbnd_ln1)
(L.L.rlbnd_ln2_target) (S.L.rlbnd_ln2)
(L.L.rlbnd_ln3_target) (S.L.rlbnd_ln3)
(M.L.rollband_actu)


1 (S.L.rlbnd_refresh_seitenschild)

{end}

'********************************************************************
'** MCQ 24.5.2009 - Ende Trigger für AI-Scheduled-Initialisierung **
'********************************************************************


'*******************************************
' Trigger für Seitenschild

{trigger:rlbnd_seitenschildklemme_drag}
(L.S.mouse_y) -300 / (L.L.rlbnd_seitenschildklemme) + (S.L.rlbnd_seitenschildklemme) s0
l0 0 <
{if}
0 (S.L.rlbnd_seitenschildklemme)
{endif}
l0 0.7 >
{if}
(L.L.rlbnd_seitenschild_refresh) 0 =
{if}
1 (S.L.rlbnd_seitenschild_refresh)
(T.L.ev_fahrertuer_auf)
(L.$.Rollband_Seitenschild) "" $=
{if}
1 (S.L.rlbnd_refresh_seitenschild)
{else}
"" (S.$.Rollband_Seitenschild)
{endif}
{endif}
{endif}
l0 1 >
{if}
1 (S.L.rlbnd_seitenschildklemme)
{endif}
{end}

{trigger:rlbnd_seitenschildklemme_off}
(L.L.rlbnd_seitenschildklemme)
0.3 >
{if}
(T.L.ev_fahrertuer_zu)
{endif}
0 (S.L.rlbnd_seitenschildklemme)
(S.L.rlbnd_seitenschild_refresh)
{end}

'*******************************************
' Trigger für Steckschild

{trigger:bus_rollband_change_steckschild}
(L.L.rlbnd_steckschild_index) 1 + (S.L.rlbnd_steckschild_index)
1000 + (M.V.GetTerminusIndex) (S.L.rlbnd_steckschild_Termindex)

(M.L.rollband_setsteckschild)
(M.L.rollband_refreshIntIndex)
{end}

{macro:rollband_setsteckschild}
(L.L.rlbnd_steckschild_Termindex) s0
0 >=
{if}
l0 6 (M.V.GetTerminusString) (S.$.Rollband_SchildFrnt)
1 $SetLengthL $StrToFloat 1 max (S.L.rlbnd_steckschild_vis)
"..\..\Anzeigen\SteckSchilder\" (L.$.Rollband_SchildFrnt) $+ (S.$.Rollband_SchildFrnt)
{else}
0 (S.L.rlbnd_steckschild_index) (S.L.rlbnd_steckschild_vis)
"" (S.$.Rollband_SchildFrnt)
{endif}
{end}



'----------------------
' Init
'----------------------

{macro:rollband_init}
0
(S.L.rlbnd_ln1) (S.L.rlbnd_ln2) (S.L.rlbnd_ln3) (S.L.rlbnd_ziel)
1 (S.L.rlbnd_activekurbel)
(M.L.rollband_actu)

0 (S.L.rlbnd_ziel_target) (S.L.rlbnd_ziel)
-1 (L.L.rlbnd_steckschild_Termindex)
0 (S.L.rlbnd_steckschild_vis)
{end}

{macro:rollband_frame}

(L.L.elec_busbar_main) (C.L.elec_busbar_minV) >
{if}
(L.L.rlbnd_ziel_target) (L.L.rlbnd_ziel) =
{if}
(L.L.rlbnd_auf_pressed)
{if}
(L.L.rlbnd_ziel_target) 1 + (S.L.rlbnd_ziel_target)
1 (S.L.rlbnd_running) (S.L.rlbnd_running_up)
0 (S.L.rlbnd_running_dn)
(T.L.rlbnd_klick)
{else}

(L.L.rlbnd_ab_pressed)
{if}
(L.L.rlbnd_ziel_target) 1 - (S.L.rlbnd_ziel_target)
1 (S.L.rlbnd_running) (S.L.rlbnd_running_dn)
0 (S.L.rlbnd_running_up)
(T.L.rlbnd_klick)
{else}
(L.L.rlbnd_running)
{if}
(T.L.rlbnd_klick)
{endif}
0 (S.L.rlbnd_running) (S.L.rlbnd_running_up) (S.L.rlbnd_running_dn)
{endif}
{endif}
{else}
1 (S.L.rlbnd_running)
(L.L.rlbnd_ziel_target) (L.L.rlbnd_ziel) >
{if}
1 (S.L.rlbnd_running_up)
0 (S.L.rlbnd_running_dn)
{else}
1 (S.L.rlbnd_running_dn)
0 (S.L.rlbnd_running_up)
{endif}
{endif}
{else}
0 (S.L.rlbnd_running) (S.L.rlbnd_running_dn) (S.L.rlbnd_running_up)
{endif}



' Hier muss unterschieden werden zwischen Auf und Ab, da das Zählwerk sofort nach Betätigung des Tasters umspringen soll
(L.L.rlbnd_ziel) trunc s0
(L.L.rlbnd_ziel_target) (L.L.rlbnd_ziel) >
{if}
l0 (L.L.rlbnd_ziel) d trunc - (F.L.rlbnd_klinkwerk_auf) + s0
{else}
l0 (L.L.rlbnd_ziel) d trunc - (F.L.rlbnd_klinkwerk_ab) + s0
{endif}
l0 (S.L.rlbnd_1er)

(L.L.rlbnd_1er) 10 / trunc
(L.L.rlbnd_1er) 10 / d trunc - (F.L.rlbnd_10er-uebertrag) +
(S.L.rlbnd_10er)

(L.L.rlbnd_10er) 10 / trunc
(L.L.rlbnd_10er) 10 / d trunc - (F.L.rlbnd_10er-uebertrag) +
(S.L.rlbnd_100er)


(L.L.elec_busbar_main) (C.L.elec_busbar_minV) >
{if}
(L.S.Timegap) (C.L.rlbnd_vmax) * s0 (L.L.rlbnd_ziel_target) (L.L.rlbnd_ziel) - l0 min s1 l0 /-/ l1 max s0
0 = !
{if}

l0 (L.L.rlbnd_ziel) + (S.L.rlbnd_ziel)

(L.L.rlbnd_ziel) trunc
' (S.L.target_index_ext)
/-/ (L.L.rlbnd_ziel) + (S.L.rlbnd_ziel_trans) 1 - (S.L.rlbnd_ziel_trans_2)
' (L.L.target_texture) 1 + (S.L.target_texture_2)

'Aktualisierung der Strings für das Austauschen der Texturen:
(L.L.rlbnd_ziel) trunc s0
"..\..\Anzeigen\Rollband_SD79\" 1 (M.V.GetDepotStringGlobal) $+ "\" $+ (S.$.Rollband_Tex_H)
l0 4 (M.V.GetTerminusString) $+ (S.$.Rollband_Tex_V)
(L.$.Rollband_Tex_H) l0 1 + 4 (M.V.GetTerminusString) $+ (S.$.Rollband_Tex_H)

'Internen Index aktualisieren:
(M.L.rollband_refreshIntIndex)
{endif}
{endif}

'Aktualisierung der Code-Tafel:

"Linienlisten\" (L.$.yard) "_RLB.jpg" $+ $+ (S.$.Rollband_Linelist)

(L.L.rlbnd_refresh_seitenschild)
{if}
"..\..\Anzeigen\Seitenschilder\" 2 (M.V.GetDepotStringGlobal) $+ "\" $+ (L.$.SetLineTo) $RemoveSpaces $+ ".bmp" $+ (S.$.Rollband_Seitenschild)
0 (S.L.rlbnd_refresh_seitenschild)
{endif}
{end}

{macro:rollband_refreshIntIndex}
(L.L.rlbnd_steckschild_Termindex) s0 0 >=
l0 0 (M.V.GetTerminusString) "" $= ! &&
{if}
l0
{else}
(L.L.rlbnd_ziel)
{endif}
(S.L.target_index_int)
{end}

{macro:rollband_actu}
(L.L.rlbnd_ln1) trunc 0.001 + (S.L.rlbnd_ln1_bmp)
/-/ (L.L.rlbnd_ln1) + 2 / (S.L.rlbnd_ln1_trans)

(L.L.rlbnd_ln2) trunc 0.001 + (S.L.rlbnd_ln2_bmp)
/-/ (L.L.rlbnd_ln2) + 2 / (S.L.rlbnd_ln2_trans)

(L.L.rlbnd_ln3) trunc 0.001 + (S.L.rlbnd_ln3_bmp)
/-/ (L.L.rlbnd_ln3) + 2 / (S.L.rlbnd_ln3_trans)
{end}

{macro:rollband_refresh_setLineTo}

(L.L.rlbnd_ln1) s0
l0 0.5 < {if} " " {else}
l0 1.5 < {if} " " {else}
l0 2.5 < {if} "N" {else}
l0 3.5 < {if} "g" {else}
l0 4.5 < {if} "0" {else}
l0 5.5 < {if} "1" {else}
l0 6.5 < {if} "2" {else}
l0 7.5 < {if} "3" {else}
l0 8.5 < {if} "4" {else}
l0 9.5 < {if} "5" {else}
l0 10.5 < {if} "6" {else}
l0 11.5 < {if} "7" {else}
l0 12.5 < {if} "8" {else}
l0 13.5 < {if} "9" {else}
l0 14.5 < {if} "/" {else}
l0 16.5 < {if} "A" {else}
l0 17.5 < {if} "E" {else}
" "
{endif}
{endif}
{endif}
{endif}
{endif}
{endif}
{endif}
{endif}
{endif}
{endif}
{endif}
{endif}
{endif}
{endif}
{endif}

(L.L.rlbnd_ln2) s0
l0 0.5 < {if} " " {else}
l0 1.5 < {if} "E" {else}
l0 2.5 < {if} "A" {else}
l0 3.5 < {if} "h" {else}
l0 4.5 < {if} "0" {else}
l0 5.5 < {if} "1" {else}
l0 6.5 < {if} "2" {else}
l0 7.5 < {if} "3" {else}
l0 8.5 < {if} "4" {else}
l0 9.5 < {if} "5" {else}
l0 10.5 < {if} "6" {else}
l0 11.5 < {if} "7" {else}
l0 12.5 < {if} "8" {else}
l0 13.5 < {if} "9" {else}
l0 14.5 < {if} "^" {else}
" "
{endif}
{endif}
{endif}
{endif}
{endif}
{endif}
{endif}
{endif}
{endif}
{endif}
{endif}
{endif}
{endif}
{endif}
{endif} $+

(L.L.rlbnd_ln3) s0
l0 0.5 < {if} " " {else}
l0 1.5 < {if} "E" {else}
l0 2.5 < {if} "N" {else}
l0 3.5 < {if} "A" {else}
l0 4.5 < {if} "0" {else}
l0 5.5 < {if} "1" {else}
l0 6.5 < {if} "2" {else}
l0 7.5 < {if} "3" {else}
l0 8.5 < {if} "4" {else}
l0 9.5 < {if} "5" {else}
l0 10.5 < {if} "6" {else}
l0 11.5 < {if} "7" {else}
l0 12.5 < {if} "8" {else}
l0 13.5 < {if} "9" {else}
l0 14.5 < {if} "\" {else}
" "
{endif}
{endif}
{endif}
{endif}
{endif}
{endif}
{endif}
{endif}
{endif}
{endif}
{endif}
{endif}
{endif}
{endif}
{endif} $+ (S.$.SetLineTo)
{end}

Konfiguration des Texturtausches:

Ein neuer TexChangeMaster wird hinzugefügt
* Name der Textur, die in der X-Datei verwendet wird und getauscht werden soll
* Variablennummer (Integer), die zum Wechseln der Textur herangezogen werden soll

[newtexchangemaster]
linienband1.bmp
rlbnd_ln1_bmp

[entries]
18
Rollband_Ln1_01.bmp
Rollband_Ln1_02.bmp
Rollband_Ln1_03.bmp
Rollband_Ln1_04.bmp
Rollband_Ln1_05.bmp
Rollband_Ln1_06.bmp
Rollband_Ln1_07.bmp
Rollband_Ln1_08.bmp
Rollband_Ln1_09.bmp
Rollband_Ln1_10.bmp
Rollband_Ln1_11.bmp
Rollband_Ln1_12.bmp
Rollband_Ln1_13.bmp
Rollband_Ln1_14.bmp
Rollband_Ln1_15.bmp
Rollband_Ln1_16.bmp
Rollband_Ln1_17.bmp
Rollband_Ln1_18.bmp

[newtexchangemaster]
linienband2.bmp
rlbnd_ln2_bmp

[entries]
16
Rollband_Ln2_01.bmp
Rollband_Ln2_02.bmp
Rollband_Ln2_03.bmp
Rollband_Ln2_04.bmp
Rollband_Ln1_05.bmp
Rollband_Ln1_06.bmp
Rollband_Ln1_07.bmp
Rollband_Ln1_08.bmp
Rollband_Ln1_09.bmp
Rollband_Ln1_10.bmp
Rollband_Ln1_11.bmp
Rollband_Ln1_12.bmp
Rollband_Ln1_13.bmp
Rollband_Ln2_14.bmp
Rollband_Ln2_15.bmp
Rollband_Ln2_16.bmp


[newtexchangemaster]
linienband3.bmp
rlbnd_ln3_bmp

[entries]
18
Rollband_Ln1_01.bmp
Rollband_Ln1_02.bmp
Rollband_Ln1_03.bmp
Rollband_Ln1_04.bmp
Rollband_Ln1_05.bmp
Rollband_Ln1_06.bmp
Rollband_Ln1_07.bmp
Rollband_Ln1_08.bmp
Rollband_Ln1_09.bmp
Rollband_Ln1_10.bmp
Rollband_Ln1_11.bmp
Rollband_Ln1_12.bmp
Rollband_Ln1_13.bmp
Rollband_Ln1_14.bmp
Rollband_Ln1_15.bmp
Rollband_Ln1_16.bmp
Rollband_Ln1_17.bmp
Rollband_Ln1_18.bmp